1. Starter Tour

Let's look at what's already built

Game Scene Tree

All familiar nodes: Node2D, Sprite2D, Area2D, Timer, Label, AudioStreamPlayer

Bird Scene

bird.tscn

Same structure as Fruit Frenzy's basket and Pong's ball

Area2D + visual + collision shape = detectable game object

Pipe Pair Scene

pipe_pair.tscn

Three Area2Ds: two pipes + one invisible scoring trigger

Groups: "pipe" = death, "score_zone" = +1 point

Pre-Built: Bird (Starter)

bird.gd — what's already there

extends Area2D

const GRAVITY = 800
const FLAP_STRENGTH = -250
const MAX_FALL_SPEED = 400
var velocity = Vector2.ZERO
var alive = true

func _process(delta):
    if not alive:
        return
    # === TODO 1: Gravity ===
    # === TODO 2: Flap ===
    rotation = clamp(velocity.y / 400.0, -0.5, 1.0)

func die():  ...   # Sets alive=false, tilts bird
func reset(): ...  # Resets position, velocity, rotation

Constants, alive flag, rotation, die/reset — all pre-built

Your job: fill in TODOs 1 and 2

2. Scrolling Background

The illusion of movement

The Two-Sprite Trick

scrolling_bg.gd

This script is pre-built in the starter:

extends Node2D

@export var scroll_speed = 60

func _process(delta):
    for child in get_children():
        if child is Sprite2D:
            var w = child.texture.get_width()
            child.position.x -= scroll_speed * delta
            if child.position.x <= -w:
                child.position.x += w * 2

Parallax

Different speeds = depth illusion

One @export per node: scroll_speed. Wrap width is read from the texture automatically.

Sprites use centered = false so position.x is the left edge

Run It!

The background scrolls slowly behind

The ground rushes past below

The bird sits still — but it looks like it's flying!

3. Gravity

Making things fall

The Gravity Pattern

Same formula used in real physics engines — we're doing it manually

Gravity Visualized

TODO 1: Gravity

In bird.gd — fill in TODO 1:

func _process(delta):
    if not alive:
        return

    # === TODO 1: Gravity ===
    velocity.y += GRAVITY * delta
    velocity.y = clamp(velocity.y, -MAX_FALL_SPEED, MAX_FALL_SPEED)
    position.y += velocity.y * delta

    # === TODO 2: Flap ===

    rotation = clamp(velocity.y / 400.0, -0.5, 1.0)

4. Flap Mechanic

Fighting gravity

The Flap Pattern

This creates the iconic arc: quick rise, slow peak, accelerating fall

TODO 2: Flap

In bird.gd — fill in TODO 2:

    # === TODO 1: Gravity ===
    velocity.y += GRAVITY * delta
    velocity.y = clamp(velocity.y, -MAX_FALL_SPEED, MAX_FALL_SPEED)
    position.y += velocity.y * delta

    # === TODO 2: Flap ===
    if Input.is_action_just_pressed("flap"):
        velocity.y = FLAP_STRENGTH

    rotation = clamp(velocity.y / 400.0, -0.5, 1.0)

Run It!

Bird falls under gravity and flaps on spacebar

The core Flappy Bird feel, already working!

5. Pipe Pairs & Movement

Obstacles that scroll

Pipe Pair Design

The ScoreZone Trick

An invisible Area2D sits in the gap between pipes

When the bird enters it: +1 point

Then we queue_free() it so it can't score twice

Same collision detection pattern from Fruit Frenzy — just invisible!

TODO 3: Pipe Movement

In pipe_pair.gd — fill in TODO 3:

extends Node2D

var speed = 60
var gap = 80   # Vertical gap between pipes (pixels)

func _ready():
    # Position pipes around the gap center
    $TopPipe.position.y = -gap / 2.0
    $BottomPipe.position.y = 288 + gap / 2.0
    $ScoreZone.position.y = 144

func _process(delta):
    # === TODO 3: Pipe Movement ===
    position.x -= speed * delta
    if position.x < -100:
        queue_free()

Ground as a "Pipe"

Notice the GroundCollider is in the "pipe" group

This is why groups are powerful: categorize by behavior, not identity

6. Pipe Spawning

Endless obstacles

The Spawning Pattern

1. preload() — load the scene (done once)
2. .instantiate() — create a copy
3. Set position — clamp Y within margins & smooth path
4. add_child() — add to the game

Timer triggers every 2 seconds for steady pipe flow

Two Constraints on Pipe Y

1. Margin clamping — gap must stay ≥ PIPE_MARGIN from viewport top and ground
   • PIPE_Y_MIN = PIPE_MARGIN + PIPE_GAP/2 - 144
   • PIPE_Y_MAX = 280 - PIPE_MARGIN - PIPE_GAP/2 - 144
2. Smooth path — consecutive pipes can't shift more than MAX_PIPE_SHIFT in Y
   • Use max()/min() to narrow the random range around last_pipe_y

TODO 4: Pipe Spawning

In game.gd — fill in TODO 4:

const PIPE_GAP = 80
const PIPE_MARGIN = 20
const PIPE_Y_MIN = PIPE_MARGIN + PIPE_GAP / 2 - 144
const PIPE_Y_MAX = 280 - PIPE_MARGIN - PIPE_GAP / 2 - 144
const MAX_PIPE_SHIFT = 60

var last_pipe_y = 0.0

func _on_pipe_spawn_timer_timeout():
    var pipe = pipe_scene.instantiate()
    pipe.gap = PIPE_GAP
    pipe.position.x = 550
    var min_y = max(PIPE_Y_MIN, last_pipe_y - MAX_PIPE_SHIFT)
    var max_y = min(PIPE_Y_MAX, last_pipe_y + MAX_PIPE_SHIFT)
    pipe.position.y = randf_range(min_y, max_y)
    last_pipe_y = pipe.position.y
    pipe.add_to_group("pipe_pairs")
    add_child(pipe)

Draw Order & z_index

Problem: add_child(pipe) adds pipes after Ground in the tree

Higher z_index = drawn later, regardless of tree order

The Infinite Scroll Illusion

Three layers, one illusion: the world moves, the bird stays

7. Collision & Scoring

Pipes kill, gaps score

Collision Table

Same is_in_group() pattern from Fruit Frenzy and Pong

TODO 5: Collision Handling

In game.gd — fill in TODO 5:

func _on_bird_area_entered(area):
    # === TODO 5: Collision Handling ===
    if area.is_in_group("pipe"):
        game_over()
    elif area.is_in_group("score_zone"):
        score += 1
        $ScoreLabel.text = str(score)
        $Sound/ScoreSound.play()
        area.queue_free()

Signal Flow

How the pieces connect:

8. State Machine

Managing game flow

The Problem

Without state management:

• Space triggers flap AND restart simultaneously
• Bird flaps during the "Press Space to Start" screen
• Pipes spawn before the game starts

We need a way to say: "what does Space do right now?"

State Diagram

The enum

Define all possible states at the top of game.gd:

enum State { MENU, COUNTDOWN, PLAYING, DYING, SCORE }
var current_state = State.MENU

Named constants are clearer than magic numbers: State.PLAYING vs 2

State-Based Logic

Check the current state and act accordingly:

if current_state == State.MENU:
    # what to do in MENU state
elif current_state == State.COUNTDOWN:
    # countdown runs itself via await
elif current_state == State.PLAYING:
    # what to do in PLAYING state
elif current_state == State.DYING:
    # freeze runs itself via await
elif current_state == State.SCORE:
    # what to do in SCORE state

Every frame, check the current state and act accordingly

Same if/elif pattern you already know from Python!

TODO 6: State Machine

In game.gd — fill in TODO 6:

func _process(_delta):
    # === TODO 6: State Machine ===
    if current_state == State.MENU:
        if Input.is_action_just_pressed("flap"):
            start_countdown()
    elif current_state == State.COUNTDOWN:
        pass  # Countdown runs itself via await
    elif current_state == State.PLAYING:
        pass  # Bird and pipes update themselves
    elif current_state == State.DYING:
        pass  # Freeze runs itself via await
    elif current_state == State.SCORE:
        if Input.is_action_just_pressed("flap"):
            restart()

Transition Functions

Each transition changes state and updates the game:

func start_countdown():     # MENU -> COUNTDOWN
    current_state = State.COUNTDOWN
    # ... 3-2-1 with await, then start_game()

func start_game():           # COUNTDOWN -> PLAYING
    current_state = State.PLAYING
    $Bird.alive = true
    $PipeSpawnTimer.start()

func game_over():            # PLAYING -> DYING
    current_state = State.DYING
    # ... freeze everything, then show_score_screen()

func show_score_screen():    # DYING -> SCORE
    current_state = State.SCORE

func restart():              # SCORE -> MENU (via show_menu)
    # ... clean up, reset bird, unfreeze, show_menu()

These are already pre-built in the starter!

Now remove $PipeSpawnTimer.start() from _ready() — start_game() handles it

Uncomment show_menu() in _ready() — the state machine now controls the game flow

Why State Machines Matter

State machines appear in every game: menus, player states, enemy AI

9. Menus

Extending the state machine

The Full Menu Flow

Two states need input, three transition automatically

Countdown: await

Pre-built in the starter — start_countdown():

func start_countdown():
    current_state = State.COUNTDOWN
    $ReadyLabel.text = "3"
    await get_tree().create_timer(1.0).timeout
    $ReadyLabel.text = "2"
    await get_tree().create_timer(1.0).timeout
    $ReadyLabel.text = "1"
    await get_tree().create_timer(1.0).timeout
    $ReadyLabel.visible = false
    start_game()

Dying & Score Screen

Pre-built in the starter — game_over() and show_score_screen():

func game_over():
    current_state = State.DYING
    $Bird.die()
    $PipeSpawnTimer.stop()
    $Sound/HitSound.play()
    $Background.set_process(false)    # Freeze!
    $Ground.set_process(false)        # Freeze!
    get_tree().call_group("pipe_pairs", "set_process", false)
    await get_tree().create_timer(1.0).timeout
    show_score_screen()

func show_score_screen():
    current_state = State.SCORE
    $GameOverLabel.text = "Score: " + str(score) + \
        "\nPress Space to Continue"
    $GameOverLabel.visible = true

10. Sound & Polish

The finishing touch

TODO 7: Hit Sound

In game.gd — already included in game_over():

func game_over():
    current_state = State.DYING
    $Bird.die()
    $PipeSpawnTimer.stop()
    $Sound/HitSound.play()            # <-- Hit sound
    $Background.set_process(false)
    $Ground.set_process(false)
    get_tree().call_group("pipe_pairs", "set_process", false)
    await get_tree().create_timer(1.0).timeout
    show_score_screen()

Sound Summary

The Complete Game

Let's play — who can beat score 5?

11. Summary

What we learned today

New Concepts

The Journey So Far

5 games, 20+ concepts — all building on each other

Concept Map

Exercises

1. Flap Sound: Add get_parent().get_node("Sound/FlapSound").play() in bird.gd's flap section
2. Difficulty Tuning: Try GRAVITY=600/1000, FLAP_STRENGTH=-200/-300, change PIPE_GAP to 60 or 100
3. Score-Based Speed: Every 5 points, increase pipe speed +10 and decrease spawn timer -0.1s
4. High Score: Track best score across restarts, show on Game Over

What's Next

From manual physics to built-in physics. Let's go!